Actions on roots and coroots

In the following functions, the optional parameter basis determines which basis the roots are given with respect to: "standard" for the standard basis of the root space; "root" for the basis of simple (co)roots; "weight" for the basis of simple (co)weights.

RootGSet( W ) : GrpCox -> GSet

CorootGSet( W ) : GrpCox -> GSet

    basis: MonStgElt                    Default: "standard"

The G-set of the Coxeter group W acting on the (co)roots.

Example GrpCox_GSets (H36E9)

> W := CoxeterGroup( "B3" );
> X := RootGSet( W );
> r := Root( W, 5 );
> r;
(0 1 1)
> Image( W.1, X, r );  
(1 1 1)

RootAction( W ) : GrpCox -> Map

CorootAction( W ) : GrpCox -> Map

    basis: MonStgElt                    Default: "standard"

The map X x W to X giving the action of the Coxeter group W on the (co)root space X.

Example GrpCox_CorootAction (H36E10)

> W := CoxeterGroup( "B3" );
> act := CorootAction( W );
> act( [1,-2,1], W.1 );           
(-3 -2  1)

ReflectionGroup( W ) : GrpCox -> GrpMat, Map

CoreflectionGroup( W ) : GrpCox -> GrpMat, Map

    basis: MonStgElt                    Default: "standard"

The Coxeter group W as a real reflection group (ie. as a matrix group over some subfield of R) acting on the (co)root space, and the isomorphism from W to the (co)reflection group.

Example GrpCox_ReflectionGroups (H36E11)

> W := CoxeterGroup( "B3" );
> R, h := ReflectionGroup( W );
> h( W.1*W.3 );
[-1  0  0]
[ 1  1  2]
[ 0  0 -1]