Operations on elements

g * h : GrpLieElt, GrpLieElt -> GrpLieElt

The product of g and h.

Example GrpLie_GrpLieEltProduct (H37E4)

> G := GroupOfLieType( "G2", GF(3) );
> V := VectorSpace(GF(3),2);
> SetNormalising(  G, false );
> g := elt< G | 1,2,1,2, V![2,2], <1,2>,<5,1> >;
> h := elt< G | <3,2>, V![1,2], 1 >;
> g * h;
n1 n2 n1 n2 (2 2) x1(2) x5(1) x3(2) (1 2) n1 
> SetNormalising(  G, true ); 
> g * h;
x2(1) x3(1) (2 2) n1 n2 n1 n2 n1 x4(1) 

Inverse( g ) : GrpLieElt -> GrpLieElt

The inverse of g.

Identity( G ) : GrpLie -> GrpLieElt

Id( G ) : GrpLie -> GrpLieElt

The identity of the group of Lie type G.

g ^ n : GrpLieElt, RngIntElt -> GrpLieElt

The nth power of g.

g ^ h : GrpLieElt, GrpLieELt -> GrpLieElt

The conjugate of g by h. Note that this is significantly more efficient than computing h^-1*g*h.

( g, h ) : GrpLieElt, GrpLieELt -> GrpLieElt

The commutator g^(-1)h^(-1)gh of g and h.

Normalise( g ) : GrpLieElt ->

Normalise( g ) : GrpLieElt -> GrpLieElt

Normalise the element g. The procedural form is slightly more efficient than the functional form.

Example GrpLie_GrpLieEltArith (H37E5)

> k<z> := GF(4);
> G := GroupOfLieType( "C3", k );    
> V := VectorSpace( k, 3 );
> g := elt< G | 1,2,3, <3,z>,<4,z^2>, V![1,z^2,1] >;               
> g;
n1 n2 n3 x3(z) x4(z^2) (  1 z^2   1) 
> h := elt< G | [0,1,z,1,0,z^2,1,1,z] >;
> h;
x2(1) x3(z) x4(1) x6(z^2) x7(1) x8(1) x9(z) 
> g * h^-1;
x3(1) x5(z) x6(z^2) x8(1) (z^2 z^2   z) n1 n2 n3 x3(z^2) x5(z^2) 
> g^3;
x3(z) x5(1) x7(z^2) x8(z^2) (  1   1   z) n1 n2 n3 n1 n2 n3 n1 n2 n3 x1(1) 
x2(z^2) x3(1) x4(z) x7(z) x9(z) 

Bruhat( g ) : GrpLieElte -> GrpLieElt, GrpLieElt, GrpLieElt, GrpLieElt

The Bruhat decomposition of g. This function returns elements u, h, /dot w, u' with the properties described in Subsection Bruhat normalisation and so that g=uh/dot wu'.

Example GrpLie_Bruhat (H37E6)

> k<z> := GF(4);
> G := GroupOfLieType( "C3", k );    
> V := VectorSpace( k, 3 );
> g := elt< G | 1,2,3, <3,z>,<4,z^2>, V![1,z^2,1] >;               
> Normalise( g ); 
x7(z^2) x8(z^2) (z^2 z^2   z) n1 n2 n3 x3(1) x6(z) 
> u, h, w, up := Bruhat( g );
> u; h; w; up;
x7(z^2) x8(z^2) 
(z^2 z^2   z) 
n1 n2 n3 
x3(1) x6(z) 

Random( G ) : GrpLie -> GrpLieElt

A uniformly random element of the group of Lie type G. The base ring of G must be finite.